การทำsearch
Posted: Fri Oct 11, 2019 1:56 pm
คือผมต้องการค้นหาข้อมูลเพื่อให้มาโชว์ครับ ผมต้องการดึงข้อมูลในช่วง D:F มาโชว์ในช่อง A4:B10 ครับ โดยอิงจาก B1
Excel Forum
ฟอรัม Excel, VBA และอื่นๆ ของคนไทยเพื่อประโยชน์ของทุกคนในจักรวาล (Forum Excel, VBA and others of Thai people for everyone in the universe.)
http://snasui.com/
การทำsearch
Page 1 of 2
Re: การทำsearch
Posted: Fri Oct 11, 2019 3:10 pm
ไฟล์ครับ
Re: การทำsearch
Posted: Fri Oct 11, 2019 7:49 pm
ตัวอย่างสูตรครับเซลล์ A4 คีย์
=IFERROR(INDEX(E$2:E$15,SMALL(IF(FREQUENCY(IF($D$2:$D$154=$B$1,MATCH($E$2:$E$15&$F$2:$F$15,$E$2:$E$15&$F$2:$F$15,0)),ROW($D$2:$D$15)-ROW($D$2)+1),ROW($D$2:$D$15)-ROW($D$2)+1),ROWS(A$4:A4))),"")
Ctrl+Shift+Enter > Copy ไป B4 > Copy ลงด้านล่าง
Re: การทำsearch
Posted: Tue Oct 15, 2019 9:43 am
สามารถทำได้แล้วครับแต่ตอนนี้ผมยากเพิ่มโดยให้ดูจากวันที่ด้วยครับ
เช่น
วันที่ 9/10/2019 มี SKU,สี อะไรบ้างโดยดึงข้อมูลเฉพาะวันที่ 9/10/2019 เท่านั้นครับ เราต้องแก้ตรงไหนครับหรือต้องเพิ่มตรงไหนครับ
แล้วเราสามารถเขียนสูตรให้ข้อมูลเรียงตามชื่อเลยได้ไหมครับ
เช่น
วันที่ 9/10/2019 มี SKU,สี อะไรบ้างโดยดึงข้อมูลเฉพาะวันที่ 9/10/2019 เท่านั้นครับ เราต้องแก้ตรงไหนครับหรือต้องเพิ่มตรงไหนครับ
แล้วเราสามารถเขียนสูตรให้ข้อมูลเรียงตามชื่อเลยได้ไหมครับ
Re: การทำsearch
Posted: Tue Oct 15, 2019 12:29 pm
ปรับที่ A4=IFERROR(INDEX(F$2:F$15,SMALL(IF($D$2:$D$154=$B$2,IF($E$2:$E$154=$B$1,ROW($E$2:$E$15)-ROW($E$2)+1)),ROWS(A$4:A4))),"") Ctrl+Shift+Enter > Copy ไป B4 > Copy ลงด้านล่างครับ
Re: การทำsearch
Posted: Tue Oct 15, 2019 3:44 pm
ผมลองทำแล้วครับแต่ทำยังไงข้อมูลที่ซ้ำกันถึงจะหายไปครับ เช่น sku กับ สี ตรงกัน ให้โชว์แค่ 1 ครับ
Re: การทำsearch
Posted: Tue Oct 15, 2019 5:16 pm
ลองทำตัวอย่างที่ต้องการมาดูอีกทีครับ เพราะตามที่อาจารย์คนควน ให้ไปก็แก้ได้ แต่คำถามก่อนหน้านี้แจ้งไว้อีกแบบ ก็ทำสูตรตามคำถามที่เปลี่ยนไปครับ ทำตัวอย่างและคำตอบมาอีกทีครับ 
Re: การทำsearch
Posted: Wed Oct 16, 2019 8:26 am
สิ่งที่ต้องการครับคือผมยากให้ข้อมูลขึ้นมาโชว์ใน cloum A4 : cloum B10 ครับโดยให้อิงจากข้อมูลวันที่ใน cloum A2 และข้อมูลใน cloum B2 ครับ โดยถ้า sku ใน cloum A ขึ้นมาโชว์แล้ว ช่อง B ก็จะขึ้นตามโดยสีนั้น จะต้องอิงจากช่อง A4 ด้วยครับและให้ข้อมูลขึ้นมาโชว์โดยเรียงกันครับ ถ้าข้อมูลมูลซ้ำกันให้โชว์แค่ 1 ครับ
เช่น
ข้อมูล D1:G15
วันที่ ข้อมูล sku สี
9/10/2019 123 KK WH
9/10/2019 123 KK WH
9/10/2019 123 KK BL
9/10/2019 123 KK BB
9/10/2019 123 GU BL
10/10/2019 123 KK WH
เมื่อเรากรอกข้อมูล ใน ช่อง A1 เป็น 123 และ กรอกข้อมูลในช่องวันที่ เป็น 9/10/2019 จะโชว์ข้อมูลในช่อง A4 : B10 โดยเรียงตามชื่อครับ
GU BL
KK WH
KK BL
KK BB
เช่น
ข้อมูล D1:G15
วันที่ ข้อมูล sku สี
9/10/2019 123 KK WH
9/10/2019 123 KK WH
9/10/2019 123 KK BL
9/10/2019 123 KK BB
9/10/2019 123 GU BL
10/10/2019 123 KK WH
เมื่อเรากรอกข้อมูล ใน ช่อง A1 เป็น 123 และ กรอกข้อมูลในช่องวันที่ เป็น 9/10/2019 จะโชว์ข้อมูลในช่อง A4 : B10 โดยเรียงตามชื่อครับ
GU BL
KK WH
KK BL
KK BB
Re: การทำsearch
Posted: Wed Oct 16, 2019 2:10 pm
ปรับเป็น ที่ A4=IFERROR(INDEX(F$2:F$15,SMALL(IF($D$2:$D$15=$B$2,IF($E$2:$E$15=$B$1,ROW($E$2:$E$15)-ROW($E$2)+1)),ROWS(A$4:A4))),"") Ctrl+Shift+Enter > Copy ไป B4 > Copy ลงด้านล่างครับ
Re: การทำsearch
Posted: Wed Oct 16, 2019 4:00 pm
ค่าซ้ำกันยังไม่หายไปครับแล้วข้อมูลยังไม่เรียงต่อกันครับ รบกวนด้วยครับ
Re: การทำsearch
Posted: Wed Oct 16, 2019 5:59 pm
ต้องแก้ไขตัวทำตัวอย่างให้ตรงคำถามด้วยครับ ไม่เช่นนั้นก็จะไม่เข้าใจความต้องการ และอะไรที่ไม่ให้ซ้ำระบุด้วยครับ
Re: การทำsearch
Posted: Wed Oct 16, 2019 6:05 pm
A4:B4
=IFERROR(INDEX(F:F,MOD(AGGREGATE(15,6,COUNTIF($F$2:$F$15,"<="&$F$2:$F$15)*10^8+COUNTIF($G$2:$G$15,"<="&$G$2:$G$15)*10^4+ROW($E$2:$E$15)/($E$2:$E$15=$B$1)/($D$2:$D$15=$B$2)/ISERROR(MATCH($F$2:$F$15&$G$2:$G$15,$A$3:$A3&$B$3:$B3,)),1),10^4)),"")
=IFERROR(INDEX(F:F,MOD(AGGREGATE(15,6,COUNTIF($F$2:$F$15,"<="&$F$2:$F$15)*10^8+COUNTIF($G$2:$G$15,"<="&$G$2:$G$15)*10^4+ROW($E$2:$E$15)/($E$2:$E$15=$B$1)/($D$2:$D$15=$B$2)/ISERROR(MATCH($F$2:$F$15&$G$2:$G$15,$A$3:$A3&$B$3:$B3,)),1),10^4)),"")
Re: การทำsearch
Posted: Thu Oct 17, 2019 9:17 am
ขอโทษครับผมได้ลองนำโค๊ดมาปรับใช้แต่ไม่ขึ้นครับรบกวนช่วยดูให้หน่อยครับผมต้องการดึงข้อมูลในหน้า Sheet1 มาโชว์ครับ
Re: การทำsearch
Posted: Thu Oct 17, 2019 1:29 pm
A11:B11
=IFERROR(INDEX(Sheet1!D:D,MOD(AGGREGATE(15,6,COUNTIF(Sheet1!$D$2:$D$999,"<="&Sheet1!$D$2:$D$999)*10^8+COUNTIF(Sheet1!$E$2:$E$999,"<="&Sheet1!$E$2:$E$999)*10^4+ROW(Sheet1!$E$2:$E$999)/(Sheet1!$C$2:$C$999=$S$2)/(Sheet1!$A$2:$A$999=$A$1)/ISERROR(MATCH(Sheet1!$D$2:$D$999&Sheet1!$E$2:$E$999,$A$10:$A10&$B$10:$B10,)),1),10^4)),"")
ใช้ได้ 999 Row
=IFERROR(INDEX(Sheet1!D:D,MOD(AGGREGATE(15,6,COUNTIF(Sheet1!$D$2:$D$999,"<="&Sheet1!$D$2:$D$999)*10^8+COUNTIF(Sheet1!$E$2:$E$999,"<="&Sheet1!$E$2:$E$999)*10^4+ROW(Sheet1!$E$2:$E$999)/(Sheet1!$C$2:$C$999=$S$2)/(Sheet1!$A$2:$A$999=$A$1)/ISERROR(MATCH(Sheet1!$D$2:$D$999&Sheet1!$E$2:$E$999,$A$10:$A10&$B$10:$B10,)),1),10^4)),"")
ใช้ได้ 999 Row
Re: การทำsearch
Posted: Sat Oct 19, 2019 11:50 am
ได้แล้วขอบคุณมากครับ ขอสอบถามเพิ่มอีกนิดครับ ถ้าผมต้องการดูเป็นผลรวมโดยไม่ต้องอิงจากวันที่ แต่เป็นวันที่ทั้งหมด ได้ไหมครับ
=IFERROR(INDEX(Sheet1!D:D,MOD(AGGREGATE(15,6,COUNTIF(Sheet1!$D$2:$D$999,"<="&Sheet1!$D$2:$D$999)*10^8+COUNTIF(Sheet1!$E$2:$E$999,"<="&Sheet1!$E$2:$E$999)*10^4+ROW(Sheet1!$E$2:$E$999)/(Sheet1!$C$2:$C$999=$S$2)/(Sheet1!$A$2:$A$999=$A$1)/ISERROR(MATCH(Sheet1!$D$2:$D$999&Sheet1!$E$2:$E$999,$A$10:$A10&$B$10:$B10,)),1),10^4)),"")
=IFERROR(INDEX(Sheet1!D:D,MOD(AGGREGATE(15,6,COUNTIF(Sheet1!$D$2:$D$999,"<="&Sheet1!$D$2:$D$999)*10^8+COUNTIF(Sheet1!$E$2:$E$999,"<="&Sheet1!$E$2:$E$999)*10^4+ROW(Sheet1!$E$2:$E$999)/(Sheet1!$C$2:$C$999=$S$2)/(Sheet1!$A$2:$A$999=$A$1)/ISERROR(MATCH(Sheet1!$D$2:$D$999&Sheet1!$E$2:$E$999,$A$10:$A10&$B$10:$B10,)),1),10^4)),"")
Re: การทำsearch
Posted: Sat Oct 19, 2019 4:36 pm
=IFERROR(INDEX(Sheet1!D:D,MOD(AGGREGATE(15,6,COUNTIF(Sheet1!$D$2:$D$999,"<="&Sheet1!$D$2:$D$999)*10^8+COUNTIF(Sheet1!$E$2:$E$999,"<="&Sheet1!$E$2:$E$999)*10^4+ROW(Sheet1!$E$2:$E$999)/(Sheet1!$C$2:$C$999=$S$2)/ISERROR(MATCH(Sheet1!$D$2:$D$999&Sheet1!$E$2:$E$999,$A$10:$A10&$B$10:$B10,)),1),10^4)),"")
Re: การทำsearch
Posted: Mon Oct 21, 2019 8:30 am
ถ้าเรายากเพิ่มช่วงข้อมูลสามารถแก้ 999 เพิ่มได้เลยใช่ไหมครับ
Re: การทำsearch
Posted: Mon Oct 21, 2019 9:12 am
ลองเปลี่ยนดูเลยครับ
กด ctrl+h จะได้หน้าต่างแทนที่ ~~> คีย์ 999 ที่ช่องบน ~~> คีย์ค่าบรรทัดใหม่ที่ช่องล่าง ~~> replace all
กด ctrl+h จะได้หน้าต่างแทนที่ ~~> คีย์ 999 ที่ช่องบน ~~> คีย์ค่าบรรทัดใหม่ที่ช่องล่าง ~~> replace all
Re: การทำsearch
Posted: Mon Oct 21, 2019 9:28 am
ผมลองเปลี่ยนเป็น 5000 ดูครับแต่ เวลานำข้อมูลไปใส่ถึง row 5000 ข้อมูลกับไม่รวมครับตามสูตรครับ
Re: การทำsearch
Posted: Mon Oct 21, 2019 9:39 am
=IFERROR(INDEX(Sheet1!D:D,MOD(AGGREGATE(15,6,COUNTIF(Sheet1!$D$2:$D$9999,"<="&Sheet1!$D$2:$D$9999)*10^10+COUNTIF(Sheet1!$E$2:$E$9999,"<="&Sheet1!$E$2:$E$9999)*10^5+ROW(Sheet1!$E$2:$E$9999)/(Sheet1!$C$2:$C$9999=$S$2)/ISERROR(MATCH(Sheet1!$D$2:$D$9999&Sheet1!$E$2:$E$9999,$A$10:$A10&$B$10:$B10,)),1),10^5)),"")