Excel Forum

เรียนอาจารย์

ผมมีเรื่องรบกวนสอบถามวิธีคำนวณเวลาในการทำงานของพนักงานเพื่อหาเวลาพักของพนักงานแต่ละคน โดยมีเวลาเข้า และออก ซึ่งจะรบกวนขอสูตรในการคำนวณตามไฟล์แนบด้วยครับ

ขอบคุณครับ

ค่อย ๆ ถามตอบกันไปครับ

เวลาเข้า เข้าพัก ออก ออกพัก ของพนักงานและละ ID สังเกตจากข้อมูลไหน อย่างไร เพื่อจะหยิบค่ามาใช้ได้ถูกต้องครับ

เรียนอาจารย์
ข้อมูลดิบ จะมีตั้งแต่ A3:C12 ครับ Column C และ D เป็นข้อมูลที่ใช้สูตรทำขึ้นมาเพื่อให้เป็นเวลาครับ
Column A3 จะเป็น Id พนักงาน
Column B3 จะเป็น วันที่พนักงานมาทำงาน
Column C3 จะเป็น เป็นเวลาที่พนักงานเข้าทำงาน + เวลาเข้าพัก และออกพัก จนเวลาออกงานครับ

ส่วนตารางแสดงผล
เอาข้อมูลมาจากตารางข้อมูลดิบครับ เพื่อให้แสดงผลออกมาในตารางแสดงผล ตามตัวอย่าง โดยดึงข้อมูลมาจากข้อมูลดิบครับ

รบกวนขอคำแนะนำด้วยครับ

C19
=SMALL(IF($B19=$A$3:$A$12,$E$3:$E$12+0),COLUMN(A1))
กดรับสูตร array

G19
=F19-C19

H19
=E19-D19

จากนั้นปรับ format > time หรือ custom

เรียนอาจารย์

ผมได้ทดลองใช้สูตรที่ให้มาแล้วครับ สามารถใช้งานได้ดีครับ แต่เมื่อใช้กับ Cell อื่นพบว่าข้อมูลซ้ำกันครับ และถ้ามีวันที่มากกว่า 1 วัน ข้อมูลจะซ้ำเหมือนกันครับ รบกวนขอคำแนะนำด้วยครับ

ขอบคุณครับ

เรียนอาจารย์

รบกวนขอคำแนะนำในกรณีนี้ด้วยครับ

ขอบคุณครับ

เมื่อมีวันที่เข้ามาเกี่ยวข้องด้วย ช่วยแปลงวันที่ในคอลัมน์ D ของชีต Data ให้เป็นวันที่เสียก่อนแล้วค่อยแนบไฟล์นั้นมาใหม่ครับ

เรียนอาจารย์

ผมได้ทำการแปลงวันที่ใน Sheet Data column B เรียบร้อยแล้วครับ รบกวนแนะนำสูตรที่ใช้ในกรณีนี้ด้วยครับ ซึ่งวันที่จะกำหนดไว้ใน column B ครับ

ขอบคุณครับ

ตัวอย่างสูตรตามด้านล่างครับ

1. ที่ C6 คีย์
   =INDEX(data!$E$3:$E$26+0,MATCH(1,IF(data!$A$3:$A$26=$B6,IF(data!$B$3:$B$26=$A6,1)),0))
   Ctrl+Shift+Enter > Copy ลงด้านล่าง
2. ที่ H6 คีย์
   =LOOKUP(2,1/((data!$A$3:$A$26=$B6)*(data!$B$3:$B$26=$A6)),data!$E$3:$E$26)+0
   Enter > Copy ลงด้านล่าง
3. ที่ D6 คีย์
   =IFERROR(INDEX(data!$E$3:$E$26,SMALL(IF(data!$A$3:$A$26=$B6,IF(data!$B$3:$B$26=$A6,IF(data!$E$3:$E$26+0>$C6,IF(data!$E$3:$E$26+0<$H6,ROW(data!$A$3:$A$26)-ROW(data!$A$3)+1)))),COLUMNS($D6:D6))),0)
   Ctrl+Shift+Enter > Copy ไปด้านขวาถึง G6 แล้ว Copy ลงด้านล่าง

!

Note: Ctrl+Shift+Enter เป็นการสร้างสูตร Array โดยสามารถเลือกดำเนินการตามข้อ 1 หรือ 2 ด้านล่าง กรณีคีย์สูตรเอง เมื่อคีย์สูตรแล้ว แทนที่จะกด Enter ให้กดแป้น Ctrl และ Shift พร้อมกันค้างไว้แล้วกด Enter เพื่อสร้างเป็นสูตร Array กรณี Copy สูตรไปวางให้กดแป้น F2 เพื่อทำการ Edit Cell นั้นก่อน จากนั้นกดแป้น Ctrl และ Shift พร้อมกันค้างไว้แล้วตามด้วย Enter เพื่อสร้างเป็นสูตร Array หากกดแป้นถูกต้องสูตรนั้นจะมีเครื่องหมายปีกกาครอบ เช่น {=YourFormulas(...)} ปีกกานี้ไม่สามารถคีย์เข้าไปเอง จะต้องมาด้วยการกดแป้น Ctrl+Shift+Enter เท่านั้น ถ้ายังไม่เห็นปีกกาครอบสูตรแสดงว่ากดแป้นให้รับสูตรไม่ถูกต้อง การแก้ไขเปลี่ยนแปลงสูตร Array จะต้องกดแป้นให้รับสูตรด้วย Ctrl+Shift+Enter ทุกครั้ง

ขอบคุณอาจารย์มากครับ สามารถใช้ประโยชน์ได้มากเลยครับ