Excel Forum

รบกวนสอบถามหน่อยครับ พอจะมีวิธี หรือสูตรจัดเรียงตัวเลขหรือเปล่าครับ ตามไฟล์แนบ มีตัวเลขจาก 1 ถึง ... ต้องการนำมาจัดเรียงใหม่ เริ่มจาก 1 ไปถึง เลขสุดท้าย บางตัวเลขอาจจะมีมากกว่า 1 ตัว ก็ให้เรียงเป็น 1 1 1 2 2 2 2 ไปเรื่อยๆ ให้อยู่ตัวละแถว บางตัวเลขโดน Merge อยู่เซลเดียวกัน แต่มีเว้นวรรคคั่น

**ไฟล์ถูกแปลมาจาก PDF เป็นลักษณะ Balloon หมายเลข ชี้ไปที่ชิ้นงานแต่ละชิ้น เลยหาวิธีเช็คจำนวนว่าถูกต้องหรือไม่

ตัวอย่างสูตรครับ

เซลล์ O1 คีย์

=IFERROR(AGGREGATE(15,6,MID(SUBSTITUTE(TRIM(CONCAT($A$1:$N$27&" "))," ",REPT(" ",50)),50*(ROW($1:$1000)-1)+1,50*ROW($1:$1000)^0)+0,ROWS(O$1:O1)),"")

ลอง Enter อย่างเดียวเพื่อรับสูตรดูก่อน หากไม่ได้ให้ Edit เซลล์ (คลิกเซลล์สูตรแล้วกดแป้น F2) จากนั้น Ctrl+Shift+Enter เพื่อรับสูตร แล้ว Copy ลงด้านล่าง

ลองทำตามอาจารย์แล้ว ไม่มีผลลัพธ์อะไรขึ้นเลยครับ

...

Excel เวอร์ชั่น ที่ท่านเจ้าของคำถามอาจจะ ไม่รองรับ CONCAT

ลองปรับไปใช้ คอลัมน์ ช่วย

P1
=IFERROR((TRIM(MID(SUBSTITUTE(TRIM(INDEX($A$1:$N$27,AGGREGATE(15,6,ROW($A$1:$A$27)/ISTEXT($A$1:$N$27),COLUMNS($A1:A1)),AGGREGATE(15,6,COLUMN($A$1:$AZ$1)/(ISTEXT($A$1:$N$27)),COLUMNS($R$2:R2))))," ",REPT(" ",20)),ROWS(P$1:P1)*20-19,20)))+0,"")
Copy ไปถึง Z27

AA1
=IFERROR(SMALL($A$1:$Z$27,ROWS($AA$1:AA1)),"")

** สนับสนุนฟอรั่ม กรุณา คลิกโฆษณาที่หน้าเพจ***

แมวใหญ่ Bigcat9
RCA พระราม9 กรุงเทพฯ

...

เนื่องจากบางไฟล์ที่แปลงมามีข้อมูลมากกว่าตัวอย่าง ผมได้ลองปรับสูตรแล้ว แต่ข้อมูลมาไม่ครบ รบกวนช่วยดูให้หน่อยครับ โดยผมกำหนดให้ A1:AZ300 เป็นพื้นที่ของไฟล์ที่แปลงมา BA1:BZ20 เป็นพื้นที่แยกตัวเลขที่รวมกันในเซลเดียว CA1:CA500 สำหรับแยกตัวเลขจาก A1:BZ300

Jirawat namrach wrote: Fri May 03, 2024 3:12 pm เนื่องจากบางไฟล์ที่แปลงมามีข้อมูลมากกว่าตัวอย่าง ผมได้ลองปรับสูตรแล้ว แต่ข้อมูลมาไม่ครบ รบกวนช่วยดูให้หน่อยครับ โดยผมกำหนดให้ A1:AZ300 เป็นพื้นที่ของไฟล์ที่แปลงมา BA1:BZ20 เป็นพื้นที่แยกตัวเลขที่รวมกันในเซลเดียว CA1:CA500 สำหรับแยกตัวเลขจาก A1:BZ300

ถ้าข้อมูลมาครบ คำตอบนั้น ควรเป็นเท่าใดครับ?


** สนับสนุนฟอรั่ม กรุณา คลิกโฆษณาที่หน้าเพจ***

แมวใหญ่ Bigcat9
RCA พระราม9 กรุงเทพฯ

...

จากไฟล์ตัวอย่าง ช่วงเซล A1:AZ300 มีข้อมูลตัวเลขที่อยู่ในเซลเดียวกัน (ไฮไลท์สีฟ้า) ต้องถูกแยกตัวเลขไปไว้ใน BA1:BZ20 ครับ แต่ตอนนี้มาไม่ครบ

...


AJ1

=IFERROR((MID(SUBSTITUTE(INDEX($A$1:$AH$300,AGGREGATE(15,6,ROW($A$1:$A$300)/ISTEXT($A$1:$AH$300),COLUMNS($AJ1:AJ1)),AGGREGATE(15,6,COLUMN($A$1:$AH$1)/INDEX(ISTEXT($A$1:$AH$300),AGGREGATE(15,6,ROW($A$1:$A$300)/ISTEXT($A$1:$AH$300),COLUMNS($AJ1:AJ1)),0),1))," ",REPT(" ",100)),ROWS(AJ$1:AJ1)*100-99,100))+0,"")

Copy ลงไป และไปทางขวา

BG1

=IFERROR(SMALL($A$1:$BF$300,ROWS(BG$1:BG1)),"")

Copy ลงไป



** สนับสนุนฟอรั่ม กรุณา คลิกโฆษณาที่หน้าเพจ***

แมวใหญ่ Bigcat9
RCA พระราม9 กรุงเทพฯ

...

ขอบคุณมากครับ