Page 1 of 1
สอบถามเรื่องการจัดกลุ่มลูกค้า
Posted: Thu Oct 19, 2023 3:37 pm
by modkore88
มีข้อมูลดิบลูกค้ามาครับ มีประเภทหนี้ PL และ NPL
ต้องการจัดกลุ่ม
กลุ่ม 1.มีหนี้ PL ทั้งหมด
กลุ่ม 2.มีหนี้ NPL ทั้งหมด
กลุ่ม 3.มีทั้งหนี้ PL และ NPL ในรายเดียวกัน
แนบข้อมูลมาให้ด้วยครับ สิ่งที่ต้องการอยู่ด้านขวา
Re: สอบถามเรื่องการจัดกลุ่มลูกค้า
Posted: Thu Oct 19, 2023 5:56 pm
by norkaz
...
F3:Gxx
=IFERROR(INDEX($E$1:$E$18,AGGREGATE(15,6,ROW($B$3:$B$18)/($B3=$B$3:$B$18),COLUMNS($F3:F3))),E3)
H3:Hxx
=IF(F3=G3,F3,"PL-"&"NPL")
กลุ่ม PL
I3
=IFERROR(INDEX(B:B,AGGREGATE(15,6,ROW($H$3:$H$18)/($H$3:$H$18="PL"),ROWS(I$3:I3))),"")
Copy ไปขวา และลงล่าง
กลุ่ม NPL
N3
=IFERROR(INDEX(B:B,AGGREGATE(15,6,ROW($H$3:$H$18)/($H$3:$H$18="NPL"),ROWS(I$3:I3))),"")
Copy ไปขวา และลงล่าง
กลุ่ม PL และ NPL
S3
=IFERROR(INDEX(B:B,AGGREGATE(15,6,ROW($H$3:$H$18)/($H$3:$H$18="PL-NPL"),ROWS(I$3:I3))),"")
Copy ไปขวา และลงล่าง
**สนับสนุนฟอรั่ม กรุณาคลิกโฆษณาที่หน้าเพจ***
แมวใหญ่ Bigcat9
RCA พระราม9 กรุงเทพฯ
Re: สอบถามเรื่องการจัดกลุ่มลูกค้า
Posted: Fri Oct 20, 2023 12:50 pm
by modkore88
ขอบคุณครับ
Re: สอบถามเรื่องการจัดกลุ่มลูกค้า
Posted: Fri Oct 20, 2023 1:27 pm
by modkore88
ทดสอบทำข้อมูลเต็มๆ แล้วจำนวนลูกค้ายังไม่ตรงกันครับ
ลูกค้าทั้งหมด 357 ราย
PL+NPL+(PL+NPL)=360 ราย
แก้ไขยังได้ได้บ้างครับ
Re: สอบถามเรื่องการจัดกลุ่มลูกค้า
Posted: Fri Oct 20, 2023 2:38 pm
by norkaz
...
กรณีข้อมูลมากๆ ลองปรับไปแบบนี้ครับ
ทั้งหมดควรได้ 357 สาเหตุที่ เจ้าของคำถามนับได้ 360 เนื่องจาก นับ ค่าว่าง บวกเข้าไป 3 รายการครับ
G3:Hxxx
=COUNT(INDEX(MATCH($B3&G$2,$B$3:$B$587&$E$3:$E$587,0),0))
I3
=IF(AND(G3=1,H3=1),"PL+NPL",IF(G3=1,"PL","NPL"))
กลุ่ม PL
J3
=IFERROR(INDEX(B:B,AGGREGATE(15,6,ROW($I$3:$I$587)/($I$3:$I$587="PL"),ROWS(J$2:J2))),"")
Copy ไปขวา และลงล่าง
กลุ่ม NPL
O3
=IFERROR(INDEX(B:B,AGGREGATE(15,6,ROW($I$3:$I$587)/($I$3:$I$587="NPL"),ROWS(O$2:O2))),"")
Copy ไปขวา และลงล่าง
กลุ่ม PL และ NPL
T3
=IFERROR(INDEX(B:B,AGGREGATE(15,6,ROW($I$3:$I$587)/($I$3:$I$587="PL+NPL"),ROWS(T$2:T2))),"")
**สนับสนุนฟอรั่ม กรุณาคลิกโฆษณาที่หน้าเพจ***
แมวใหญ่ Bigcat9
RCA พระราม9 กรุงเทพฯ