Page 1 of 1
ต้องการเพิ่มเงื่อนในสูตร INDEX,SMALL ค่ะ
Posted: Wed Jun 21, 2023 9:15 pm
by suka
ขอความช่วยเหลือปรับเพิ่มเงื่อนไขในสูตรค่ะ
ที่เซลล์ H2:I8 ใช้สูตร =IFERROR(INDEX($C$2:$C$8,SMALL(IF($F$2:$F$8=$I$1,ROW($B$2:$B$8)-ROW(C$2)+1),ROWS(C$2:C2))),"")
ดึงข้อมูลจากฐานข้อมูลโดยให้ดึงตามเงื่อนไขในเซลล์ I1 มาได้ตามต้องการค่ะ
ติดปัญหาต้องการให้สูตรดึงแยกค่ามาที่เซลล์ J2:K8 ตามเงื่อนไขเซลล์ J1 และ K1 ค่ะควรปรับสูตรอย่างไรดีคะ
ค่าที่ต้องการตามตัวอย่างในไฟล์แนบระบายสีเหลืองค่ะ
Re: ต้องการเพิ่มเงื่อนในสูตร INDEX,SMALL ค่ะ
Posted: Wed Jun 21, 2023 9:36 pm
by norkaz
...
J2:K5
=SUMIFS($D$2:$D$8,$B$2:$B$8,$H2,$E$2:$E$8,J$1,$F$2:$F$8,$I$1)
**สนับสนุนฟอรั่ม กรุณาช่วยคลิกโฆษณาหน้าเพจ**
Norkaz
Re: ต้องการเพิ่มเงื่อนในสูตร INDEX,SMALL ค่ะ
Posted: Wed Jun 21, 2023 10:15 pm
by norkaz
...
หรือแบบสูตรเดียว
I2
=IF(I$1="KJ",SUMIFS($C$2:$C$8,$B$2:$B$8,$H2,$F$2:$F$8,$I$1),SUMIFS($D$2:$D$8,$B$2:$B$8,$H2,$E$2:$E$8,I$1,$F$2:$F$8,$I$1))
Copy ไปขวา และลงล่าง
**สนับสนุนฟอรั่ม กรุณาช่วยคลิกโฆษณาหน้าเพจ**
Norkaz
Re: ต้องการเพิ่มเงื่อนในสูตร INDEX,SMALL ค่ะ
Posted: Thu Jun 22, 2023 12:41 pm
by suka
ใช้สูตร =IF(I$1="KJ",SUMIFS($C$2:$C$8,$B$2:$B$8,$H2,$F$2:$F$8,$I$1),SUMIFS($D$2:$D$8,$B$2:$B$8,$H2,$E$2:$E$8,I$1,$F$2:$F$8,$I$1))
ติดตรงชื่อเดียวกันใน 1 วันทำมากกว่า 1 รายการสูตรจะรวมค่าให้ตามที่ระบายสีแดงไว้ในไฟล์แนบค่ะ
ต้องการให้สูตรดึงข้อมูลเรียงตามรายการโดยไม่รวมค่าเข้ากัน ควรปรับสูตรอย่างไรคะ
Re: ต้องการเพิ่มเงื่อนในสูตร INDEX,SMALL ค่ะ
Posted: Thu Jun 22, 2023 1:17 pm
by norkaz
...
J2:Kxx
=IFERROR(INDEX($D:$D,AGGREGATE(15,6,ROW($B$2:$B$99)/($H2&$I$1=$B$2:$B$99&$F$2:$F$99)/(J$1=$E$2:$E$99),COUNTIF($H$2:$H2,$H2))),"")
**สนับสนุนฟอรั่ม กรุณาช่วยคลิกโฆษณาหน้าเพจ**
Norkaz
Re: ต้องการเพิ่มเงื่อนในสูตร INDEX,SMALL ค่ะ
Posted: Thu Jun 22, 2023 3:17 pm
by suka
สูตรนี้
=IFERROR(INDEX($D:$D,AGGREGATE(15,6,ROW($B$2:$B$99)/($H2&$I$1=$B$2:$B$99&$F$2:$F$99)/(J$1=$E$2:$E$99),COUNTIF($H$2:$H2,$H2))),"")
ไม่สามารถใช้กับ Excel 2007 ไหมคะ
Re: ต้องการเพิ่มเงื่อนในสูตร INDEX,SMALL ค่ะ
Posted: Thu Jun 22, 2023 3:27 pm
by norkaz
...
Excel 2007
=IFERROR(INDEX($D:$D,SMALL(IFERROR(ROW($B$2:$B$99)/($H2&$I$1&J$1=$B$2:$B$99&$F$2:$F$99&$E$2:$E$99),""),COUNTIF($H$2:$H2,$H2))),"")
Ctrl + Shift + Enter
**สนับสนุนฟอรั่ม กรุณาช่วยคลิกโฆษณาหน้าเพจ**
Norkaz
Re: ต้องการเพิ่มเงื่อนในสูตร INDEX,SMALL ค่ะ
Posted: Thu Jun 22, 2023 3:45 pm
by suka
Ctrl + Shift + Enter แล้วค่ะ ขัอมูลไม่มาค่ะ
Re: ต้องการเพิ่มเงื่อนในสูตร INDEX,SMALL ค่ะ
Posted: Thu Jun 22, 2023 4:55 pm
by norkaz
suka wrote: Thu Jun 22, 2023 3:45 pm
Ctrl + Shift + Enter แล้วค่ะ ขัอมูลไม่มาค่ะ
แนบไฟล์จริงมาดูครับ
**สนับสนุนฟอรั่ม กรุณาช่วยคลิกโฆษณาหน้าเพจ**
Norkaz
Re: ต้องการเพิ่มเงื่อนในสูตร INDEX,SMALL ค่ะ
Posted: Thu Jun 22, 2023 5:12 pm
by suka
ไฟล์แนบทดลองสูตรที่เซลล์ J2:K2 ค่ะ
Re: ต้องการเพิ่มเงื่อนในสูตร INDEX,SMALL ค่ะ
Posted: Thu Jun 22, 2023 5:41 pm
by norkaz
...
สูตรที่เขียนไป คืออันนี้
Excel 2007
=IFERROR(INDEX($D:$D,SMALL(IFERROR(ROW($B$2:$B$99)/($H2&$I$1&J$1=$B$2:$B$99&$F$2:$F$99&$E$2:$E$99),""),COUNTIF($H$2:$H2,$H2))),"")
Ctrl + Shift + Enter
ที่ผู้สอบถามแนบมา คือสูตรอื่นที่ไม่ใช่สูตรด้านบนที่ใช้กับ Excel 2007
ให้ลบสูตรอื่นๆ ทิ้งไปแล้ว ใช้ สูตรที่เขียนไปด้านบนนี้ ไปวางแทน ที่ J2
แล้ว กด Ctrl + Shift ค้างไว้ จากนั้นกด Enter
จากนั้น Copy ไปเซลล์อื่นๆ
**สนับสนุนฟอรั่ม กรุณาช่วยคลิกโฆษณาหน้าเพจ**
Norkaz
Re: ต้องการเพิ่มเงื่อนในสูตร INDEX,SMALL ค่ะ
Posted: Thu Jun 22, 2023 7:58 pm
by suka
สูตรได้ตรงตามที่ต้องการแล้วค่ะ ขอบคุณคุณ norkaz มากนะคะ