Page 1 of 1
จะเขียนสูตรเพื่อแสดงให้เห็นจำนวนนับต่อเนื่องมากกว่า 6 ได้อย่างไร
Posted: Thu Apr 20, 2023 5:22 pm
by blepuviput
เรียนท่านผู้รู้
จะเขียนสูตรในคอลัมน์ AH4 อย่างไร เพื่อแสดงให้เห็นว่ามีหรือไม่มีค่านับจากคอลัมน์ C4 ถึง AG4 ที่รวมกันมากกว่า 6 หรือไม่
ซึ่งคำตอบที่ต้องการมีวัตถุประสงค์เพื่อนำไปประยุกต์ใช้ในการ Audit ในส่วนของการเข้าทำงานเกิน 6 วันทำงานต่อเนื่องหรือไม่ครับ
และสามารถใช้ Conditional Formatting ระบายสีเหลืองกรณีที่มีค่าตรวจนับเกิน 6 วันหรือไม่ ในคอลัมน์ดังตาราง
ขอบคุณครับ
Re: จะเขียนสูตรเพื่อแสดงให้เห็นจำนวนนับต่อเนื่องมากกว่า 6 ได้อย่างไร
Posted: Thu Apr 20, 2023 9:41 pm
by Bo_ry
AH4
=IF(MAX(LEN(TEXTSPLIT(CONCAT(IF(C4:AG4,1,0)),0)))<7,"ไม่",)&"มี"
Conditional Formatting
=LEN(TEXTAFTER(CONCAT(IF($C4:C4,1,)),0,-1,,1)&TEXTBEFORE(CONCAT(IF(C4:$AG4,1,)),0,,,1))>7
Re: จะเขียนสูตรเพื่อแสดงให้เห็นจำนวนนับต่อเนื่องมากกว่า 6 ได้อย่างไร
Posted: Fri Apr 21, 2023 10:05 am
by blepuviput
เรียน K.Bo_ry
ขอบคุณมากครับสำหรับคำตอบสามารถนำมาใช้กับเครื่องที่ผมใช้ Microsoft 365 ได้
แต่ถ้าใน Excel ของเครื่องที่ใช้ทางริษัทเป็น Version เก่าค่าที่ได้เป็น#NAME? สามารถเขียนสูตรได้ไหมครับ
ขอบคุณครับ
Re: จะเขียนสูตรเพื่อแสดงให้เห็นจำนวนนับต่อเนื่องมากกว่า 6 ได้อย่างไร
Posted: Sat Apr 22, 2023 9:26 am
by snasui
blepuviput wrote: Fri Apr 21, 2023 10:05 am
Excel ของเครื่องที่ใช้ทางริษัทเป็น Version เก่าค่าที่ได้เป็น#NAME? สามารถเขียนสูตรได้ไหมครับ
เขียนได้ครับ
เพื่อประโยชน์ในการทำ Conditional Formatting ได้ง่ายขึ้นให้แทรก 2 คอลัมน์คือ C และ AI จากนั้นเขียนสูตรที่ AJ เพื่อแสดงว่ามีหรือไม่มีค่าตามเงื่อนไขดังด้านล่าง
=IF(MAX(FREQUENCY(IF(D4:AH4=1,COLUMN(D4:AH4)),IF(D4:AH4=0,COLUMN(D4:AH4))))>6,"มี","ไม่มี")
Ctrl+Shift+Enter
จากนั้นทำ Conditional Formatting โดยการคลุม D4:AH13 โดยใช้สูตรด้านล่าง
=AND(D4<>"",COUNTIFS(OFFSET($C4,0,MATCH(2,INDEX(1/($C4:C4=""),0)),1,COLUMNS($D4:D4)-MATCH(2,INDEX(1/($C4:C4=""),0))+MATCH(1,INDEX(1/(D4:$AI4=""),0),0)),1)>6)
Re: จะเขียนสูตรเพื่อแสดงให้เห็นจำนวนนับต่อเนื่องมากกว่า 6 ได้อย่างไร
Posted: Sat Apr 22, 2023 1:09 pm
by Bo_ry
AI4
=IF(OR(FREQUENCY(IF(C4:AG4,$C$3:$AG$3),IF(C4:AG4=0,$C$3:$AG$3))>6),,"ไม่")&"มี"
Conditional Formatting
=IFNA(MATCH(0,-C4:$AG4,)-1,COLUMNS(C4:$AG4))+COLUMNS($C4:C4)-IFERROR(MATCH(2,1/($C4:C4=0)),)
Re: จะเขียนสูตรเพื่อแสดงให้เห็นจำนวนนับต่อเนื่องมากกว่า 6 ได้อย่างไร
Posted: Sat Apr 22, 2023 5:31 pm
by blepuviput
เรียนท่านอาจารย์ snasui และ ท่านBo_ry
ได้คำตอบตามที่ต้องการเลยครับ ขอบคุณมากครับผม