Excel Forum

ฟอรัม Excel, VBA และอื่นๆ ของคนไทยเพื่อประโยชน์ของทุกคนในจักรวาล (Forum Excel, VBA and others of Thai people for everyone in the universe.)
http://snasui.com/

ดึงข้อมูลข้ามไฟล์

http://snasui.com/viewtopic.php?t=12328

Page 1 of 2

ดึงข้อมูลข้ามไฟล์

Posted: Wed Oct 11, 2017 4:32 pm
by Benmore
ขอสอบถามหน่อยค่ะ คือต้องการจะดึงข้อมูลข้ามไฟล์ โดยมีเงื่อนไข
เช่น ถ้าเจอรหัส 000001 ในไฟล์ 1 ให้นำเอาข้อมูลในแถว total by employee คอลัมน์ M
มาแสดงในไฟล์ 2 ในคอลัมน์ G ของแถวรหัส 000001 ในไฟล์ 2 ต้องเขียนสูตรประมาณไหนค่ะ

Re: ดึงข้อมูลข้ามไฟล์

Posted: Wed Oct 11, 2017 4:50 pm
by puriwutpokin
ที่ file 2.xls ชีท Monthly_Sep'17 ตำแหน่ง G6=INDEX('[1.xls]Monthly Attendance Report'!$M$7:$M$534,SMALL(IF(ISNUMBER(FIND("Total by Employee :",'[1.xls]Monthly Attendance Report'!$B$7:$B$534)),ROW('[1.xls]Monthly Attendance Report'!$M$7:$M$534)-ROW('[1.xls]Monthly Attendance Report'!$M$7)+1),ROWS($G$6:$G6))) แล้วกด Ctrl+Shift+Enter คัดลอกลงครับ

Re: ดึงข้อมูลข้ามไฟล์

Posted: Wed Oct 11, 2017 5:40 pm
by eyepop99
คีย์สูตรช่อง G6 file 2.xls ชีท Monthly_Sep'17

G6 =INDEX('[1.xls]Monthly Attendance Report'!M$1:M$534,MIN(IF('[1.xls]Monthly Attendance Report'!$B$1:$B$534=$B6,ROW('[1.xls]Monthly Attendance Report'!$B$1:$B$534)+COUNTIF('[1.xls]Monthly Attendance Report'!$B$1:$B$534,$B6))))

กด Ctrl+Shift+Enter
ลากลง และ ลากไปทางด้านซ้ายครับ

Re: ดึงข้อมูลข้ามไฟล์

Posted: Thu Oct 12, 2017 9:02 am
by Benmore
eyepop99 wrote:คีย์สูตรช่อง G6 file 2.xls ชีท Monthly_Sep'17

G6 =INDEX('[1.xls]Monthly Attendance Report'!M$1:M$534,MIN(IF('[1.xls]Monthly Attendance Report'!$B$1:$B$534=$B6,ROW('[1.xls]Monthly Attendance Report'!$B$1:$B$534)+COUNTIF('[1.xls]Monthly Attendance Report'!$B$1:$B$534,$B6))))

กด Ctrl+Shift+Enter
ลากลง และ ลากไปทางด้านซ้ายครับ
ลองทำแล้ว ขึ้น #REF! ล่ะก้อค่าเป็น 0 ตลอดค่ะ เพราะอะไรค่ะ?

Re: ดึงข้อมูลข้ามไฟล์

Posted: Thu Oct 12, 2017 9:11 am
by Benmore
Benmore wrote:
eyepop99 wrote:คีย์สูตรช่อง G6 file 2.xls ชีท Monthly_Sep'17

G6 =INDEX('[1.xls]Monthly Attendance Report'!M$1:M$534,MIN(IF('[1.xls]Monthly Attendance Report'!$B$1:$B$534=$B6,ROW('[1.xls]Monthly Attendance Report'!$B$1:$B$534)+COUNTIF('[1.xls]Monthly Attendance Report'!$B$1:$B$534,$B6))))

กด Ctrl+Shift+Enter
ลากลง และ ลากไปทางด้านซ้ายครับ
ลองทำแล้วหลังๆก็ ขึ้น #REF! ล่ะก้อค่าเป็น 0 ตลอดค่ะ เพราะอะไรค่ะ?

Re: ดึงข้อมูลข้ามไฟล์

Posted: Thu Oct 12, 2017 10:04 am
by puriwutpokin
ลองดูที่ G6=INDEX('[1.xls]Monthly Attendance Report'!M$7:M$2620,MATCH($B6,'[1.xls]Monthly Attendance Report'!$B$7:$B$2620,0)+COUNTIF('[1.xls]Monthly Attendance Report'!$B$7:$B$2620,$B6)) คัดลอกไปทางขวาและลงล่างครับ

Re: ดึงข้อมูลข้ามไฟล์

Posted: Thu Oct 12, 2017 10:13 am
by Benmore
puriwutpokin wrote:ลองดูที่ G6=INDEX('[1.xls]Monthly Attendance Report'!M$7:M$2620,MATCH($B6,'[1.xls]Monthly Attendance Report'!$B$7:$B$2620,0)+COUNTIF('[1.xls]Monthly Attendance Report'!$B$7:$B$2620,$B6)) คัดลอกไปทางขวาและลงล่างครับ
ลองทำแล้วได้ค่ะแต่พอปิดไฟล์ทั้งหมด แล้วก็เปิดไฟล์ 2 ขึ้นมาไฟล์เดียวก็ขึ้น #VALUE! ทุกช่อง
แล้วพอแก้ไขข้อมูลในไฟล์ 1 ไฟล์ 2 ก็ไม่เปลี่ยนค่ะ

Re: ดึงข้อมูลข้ามไฟล์

Posted: Thu Oct 12, 2017 10:30 am
by puriwutpokin
การทำข้อมูลข้ามไฟล์ต้องเปิดไฟล์ทั้ง2นั้นด้วยเวลามีการเปลี่ยนแปลงครับ

Re: ดึงข้อมูลข้ามไฟล์

Posted: Thu Oct 12, 2017 10:32 am
by Benmore
puriwutpokin wrote:การทำข้อมูลข้ามไฟล์ต้องเปิดไฟล์ทั้ง2นั้นด้วยเวลามีการเปลี่ยนแปลงครับ
มีวิธีไหนที่ไม่ต้องเปิดไฟล์พร้อมกันไหมค่ะ
และถ้าจะทำ Total ในช่อง J6 แล้ว coppy มาเรื่อยๆต้องเขียนแบบไหนค่ะ

Re: ดึงข้อมูลข้ามไฟล์

Posted: Thu Oct 12, 2017 10:56 am
by puriwutpokin
รวม2ไฟล์เป็นไฟล์เดียวครับ
และถ้าจะรวมค่าผลรวมคงต้องปรับสูตรครับสำหรับเวอร์ชั่น 2003 จะยาวหน่อยครับ
เพราะค่าที่ได้จากการดึงมานั้นข้อมูลเดิมเป็น ข้อความครับ ต้องปรับเป็น
ที่ G6=IF(ISERR(INDEX('[1.xls]Monthly Attendance Report'!M$7:M$2620,MATCH($B6,'[1.xls]Monthly Attendance Report'!$B$7:$B$2620,0)+COUNTIF('[1.xls]Monthly Attendance Report'!$B$7:$B$2620,$B6))+0),0,INDEX('[1.xls]Monthly Attendance Report'!M$7:M$2620,MATCH($B6,'[1.xls]Monthly Attendance Report'!$B$7:$B$2620,0)+COUNTIF('[1.xls]Monthly Attendance Report'!$B$7:$B$2620,$B6))+0)

Re: ดึงข้อมูลข้ามไฟล์

Posted: Thu Oct 12, 2017 11:21 am
by Benmore
puriwutpokin wrote:รวม2ไฟล์เป็นไฟล์เดียวครับ
และถ้าจะรวมค่าผลรวมคงต้องปรับสูตรครับสำหรับเวอร์ชั่น 2003 จะยาวหน่อยครับ
เพราะค่าที่ได้จากการดึงมานั้นข้อมูลเดิมเป็น ข้อความครับ ต้องปรับเป็น
ที่ G6=IF(ISERR(INDEX('[1.xls]Monthly Attendance Report'!M$7:M$2620,MATCH($B6,'[1.xls]Monthly Attendance Report'!$B$7:$B$2620,0)+COUNTIF('[1.xls]Monthly Attendance Report'!$B$7:$B$2620,$B6))+0),0,INDEX('[1.xls]Monthly Attendance Report'!M$7:M$2620,MATCH($B6,'[1.xls]Monthly Attendance Report'!$B$7:$B$2620,0)+COUNTIF('[1.xls]Monthly Attendance Report'!$B$7:$B$2620,$B6))+0)
ถ้าเป็นเวอร์ชั่น 2016 ล่ะค่ะต้องปรับตรงไหนค่ะ

Re: ดึงข้อมูลข้ามไฟล์

Posted: Thu Oct 12, 2017 11:38 am
by puriwutpokin
ที่ G6=IFERROR(INDEX('[1.xls]Monthly Attendance Report'!M$7:M$2620,MATCH($B6,'[1.xls]Monthly Attendance Report'!$B$7:$B$2620,0)+COUNTIF('[1.xls]Monthly Attendance Report'!$B$7:$B$2620,$B6))+0,0)

Re: ดึงข้อมูลข้ามไฟล์

Posted: Thu Oct 12, 2017 11:52 am
by Benmore
puriwutpokin wrote:ที่ G6=IFERROR(INDEX('[1.xls]Monthly Attendance Report'!M$7:M$2620,MATCH($B6,'[1.xls]Monthly Attendance Report'!$B$7:$B$2620,0)+COUNTIF('[1.xls]Monthly Attendance Report'!$B$7:$B$2620,$B6))+0,0)
ลองทำแล้วไม่ได้ค่ะ คืออยากให้รวมข้อมูลในเซลล์ G1 ถึง I1 ที่ช่อง J1
แล้วพอลองเอาโค้ดนี้ไปใส่แทนโค้ดเดิมก็ไม่ขึ้นค่ะ ขึ้น 0.00 แล้วก็ขึ้น หน้าให้ Update value ตลอดเลยค่ะ

Re: ดึงข้อมูลข้ามไฟล์

Posted: Thu Oct 12, 2017 11:56 am
by puriwutpokin
ลองดูตามไฟล์แนบครับ ต้องเปิดทั้ง2ไฟล์นะครับ

Re: ดึงข้อมูลข้ามไฟล์

Posted: Thu Oct 12, 2017 12:30 pm
by Benmore
puriwutpokin wrote:ลองดูตามไฟล์แนบครับ ต้องเปิดทั้ง2ไฟล์นะครับ
ถ้าให้คำนวณเฉพาะที่เปนตัวเลขได้ไหมค่ะ แล้วช่องที่เปน 0 ให้ใส่ - เหมือนเดิม

Re: ดึงข้อมูลข้ามไฟล์

Posted: Thu Oct 12, 2017 12:41 pm
by eyepop99
Benmore wrote:
eyepop99 wrote:คีย์สูตรช่อง G6 file 2.xls ชีท Monthly_Sep'17

G6 =INDEX('[1.xls]Monthly Attendance Report'!M$1:M$534,MIN(IF('[1.xls]Monthly Attendance Report'!$B$1:$B$534=$B6,ROW('[1.xls]Monthly Attendance Report'!$B$1:$B$534)+COUNTIF('[1.xls]Monthly Attendance Report'!$B$1:$B$534,$B6))))

กด Ctrl+Shift+Enter
ลากลง และ ลากไปทางด้านซ้ายครับ
ลองทำแล้วหลังๆก็ ขึ้น #REF! ล่ะก้อค่าเป็น 0 ตลอดค่ะ เพราะอะไรค่ะ?

แก้ช่วงข้อมูลครับ เนื่องจากช่วงข้อมูลแรก มีถึง A534 และข้อมูลจิง มีถึง A2620 ครับ
แก้ช่วงข้อมูลให้ถูกต้อง แล้วลองดูอีกทีครับ

หรือ

G6 =INDEX('[1.xls]Monthly Attendance Report'!M$1:M$2620,MIN(IF('[1.xls]Monthly Attendance Report'!$B$1:$B$2620=$B6,ROW('[1.xls]Monthly Attendance Report'!$B$1:$B$2620)+COUNTIF('[1.xls]Monthly Attendance Report'!$B$1:$B$2620,$B6))))
Ctrl+Shift+Enter
ลากลง , ลากซ้าย ครับ

จากไฟล์นี้ ถ้าใช้เหมือนผมจะไม่สามารถทำ Total ได้ เนื่องจากข้อมูลที่ดึงมาเป็น Text จะไม่สามารถคำนวนได้ครับ

และอ้างอิ้งจากคุณ

Re: ดึงข้อมูลข้ามไฟล์

Posted: Thu Oct 12, 2017 12:44 pm
by Benmore
eyepop99 wrote:
Benmore wrote:
eyepop99 wrote:คีย์สูตรช่อง G6 file 2.xls ชีท Monthly_Sep'17

G6 =INDEX('[1.xls]Monthly Attendance Report'!M$1:M$534,MIN(IF('[1.xls]Monthly Attendance Report'!$B$1:$B$534=$B6,ROW('[1.xls]Monthly Attendance Report'!$B$1:$B$534)+COUNTIF('[1.xls]Monthly Attendance Report'!$B$1:$B$534,$B6))))

กด Ctrl+Shift+Enter
ลากลง และ ลากไปทางด้านซ้ายครับ
ลองทำแล้วหลังๆก็ ขึ้น #REF! ล่ะก้อค่าเป็น 0 ตลอดค่ะ เพราะอะไรค่ะ?

แก้ช่วงข้อมูลครับ เนื่องจากช่วงข้อมูลแรก มีถึง A534 และข้อมูลจิง มีถึง A2620 ครับ
แก้ช่วงข้อมูลให้ถูกต้อง แล้วลองดูอีกทีครับ

หรือ

G6 =INDEX('[1.xls]Monthly Attendance Report'!M$1:M$2620,MIN(IF('[1.xls]Monthly Attendance Report'!$B$1:$B$2620=$B6,ROW('[1.xls]Monthly Attendance Report'!$B$1:$B$2620)+COUNTIF('[1.xls]Monthly Attendance Report'!$B$1:$B$2620,$B6))))
Ctrl+Shift+Enter
ลากลง , ลากซ้าย ครับ
ตรงนี้แก้ได้แล้วค่ะ ติดตรงที่ผลรวมค่ะ อยากให้รวมเฉพาะข้อมูลที่เป็นตัวเลขได้ไหมค่ะ

Re: ดึงข้อมูลข้ามไฟล์

Posted: Thu Oct 12, 2017 1:04 pm
by puriwutpokin
Benmore wrote:
puriwutpokin wrote:ลองดูตามไฟล์แนบครับ ต้องเปิดทั้ง2ไฟล์นะครับ
ถ้าให้คำนวณเฉพาะที่เปนตัวเลขได้ไหมค่ะ แล้วช่องที่เปน 0 ให้ใส่ - เหมือนเดิม
ปรับที่ G6=IFERROR(INDEX('[1.xls]Monthly Attendance Report'!M$7:M$2620,MATCH($B6,'[1.xls]Monthly Attendance Report'!$B$7:$B$2620,0)+COUNTIF('[1.xls]Monthly Attendance Report'!$B$7:$B$2620,$B6))+0,"-")

Re: ดึงข้อมูลข้ามไฟล์

Posted: Thu Oct 12, 2017 1:19 pm
by Benmore
puriwutpokin wrote:
Benmore wrote:
puriwutpokin wrote:ลองดูตามไฟล์แนบครับ ต้องเปิดทั้ง2ไฟล์นะครับ
ถ้าให้คำนวณเฉพาะที่เปนตัวเลขได้ไหมค่ะ แล้วช่องที่เปน 0 ให้ใส่ - เหมือนเดิม
ปรับที่ G6=IFERROR(INDEX('[1.xls]Monthly Attendance Report'!M$7:M$2620,MATCH($B6,'[1.xls]Monthly Attendance Report'!$B$7:$B$2620,0)+COUNTIF('[1.xls]Monthly Attendance Report'!$B$7:$B$2620,$B6))+0,"-")
ทำได้แล้วค่ะ ขอบคุณมากค่ะ :thup: :thup:
ช่วยอธิบายสูตรหน่อยได้ไหมค่ะว่ามันทำงานยังไง :D

Re: ดึงข้อมูลข้ามไฟล์

Posted: Thu Oct 12, 2017 1:47 pm
by puriwutpokin
1.MATCH($B6,'[1.xls]Monthly Attendance Report'!$B$7:$B$2620,0) หาตำแหน่งของค่า $B6 ในไฟล์ 1.xls
2.COUNTIF('[1.xls]Monthly Attendance Report'!$B$7:$B$2620,$B6) นับจำนวนของค่า $B6 ในไฟล์ 1.xls
3.INDEX('[1.xls]Monthly Attendance Report'!M$7:M$2620... แสดงค่าที่ต้องการจากตำแหน่งที่หา ข้อ1 และ 2
แล้วที่ต้องบวกด้วย 0 เพื่อให้ค่าตัวเลขที่เป็นข้อความกลับมาเป็นตัวเลขเพื่อคำนวณได้ครับ
IFERROR ไว้ดักกรณีค่าที่หานั้น เออเรอร์ครับ เมื่อเจอเออเรอร์ ให้แสดงเป็น "-"
ประมาณนี้ครับ ลองคลุมที่สูตรจากภายใน มาภายนอก แล้วกด F9 เพื่อดูผลของสูตรแต่ละช่วงดูครับ
All times are UTC+07:00
Page 1 of 2

Powered by phpBB® Forum Software © phpBB Limited