:!: โปรดทราบ Image
    1. กรุณาอ่านกฎการใช้บอร์ด (Forum rules) ในตำแหน่งด้านบนของแต่ละบอร์ดครับ Image
    2. การสมัครสมาชิกเพื่อโพสต์คำถาม ดาวน์โหลดไฟล์แนบไปศึกษา ทำตามขั้นตอนด้านล่างครับ
      1. สมัครสมาชิก ดูขั้นตอนตาม Link นี้ครับ => สมัครสมาชิก กรณีลืมรหัสผ่านสามารถรับรหัสใหม่ได้ที่นี่ครับ => Reset รหัสผ่านImage
      2. Login เข้าระบบโดยคลิก Login ตรงมุมขวาบนของหน้านี้ Image กรณีมีปัญหาในการเข้าใช้งาน คลิก Link นี้เพื่อแจ้งผู้ดูแลระบบครับ => ติดต่อผู้ดูแลระบบ
    3. เมื่อ Login แล้วสามารถกำหนดการตั้งค่าส่วนตัว เช่นตั้งค่าภาษาเป็นไทยหรืออังกฤษได้ที่ Link นี้ครับ => ตั้งค่าส่วนตัว Image
    4. วิธีการตั้งและตอบกระทู้ดูได้ที่ Link นี้ครับ => วิธีการตั้งและตอบกระทู้ Image
    5. การจัดรูปแบบตัวอักษรด้วย bbcode ในช่องแสดงความคิดเห็นดูได้ที่ Link นี้ครับ => จัดรูปแบบตัวอักษร และสามารถกำหนดขนาดตัวอักษรใน Browser ได้ที่นี่ครับ ==> กำหนดขนาดตัวอักษรใน Browser Image

(Macro VBA)ต้องการดึงไฟล์มาทีละหลายๆไฟล์ นำมาแปลงไฟล์ครับ

ฟอรั่มถาม-ตอบปัญหาการใช้งาน MS Excel and VBA
Forum rules
  1. ไม่อนุญาตให้ใช้ภาษาแชทในการถาม-ตอบปัญหา ไม่ใช้คำว่า "คับ" หรือ "อ่ะครับ" แทนคำว่า "ครับ" ไม่ใช้คำว่า "เด๋ว" แทนคำว่า "เดี๋ยว" เป็นต้น เนื่องจากเมื่อแปลเป็นภาษาต่างประเทศแล้วจะให้ความหมายผิดไปจากที่ควรจะเป็น
  2. ห้ามถามโดยระบุชื่อผู้ตอบ ต้องตั้งชื่อกระทู้ให้สื่อถึงปัญหาที่จะถาม ไม่ตั้งชื่อว่า ช่วยด้วยครับ, มีปัญหามาปรึกษาครับ เป็นต้น
  3. อธิบายปัญหาและระบุคำตอบที่ต้องการมาในกระทู้ด้วยเสมอถึงแม้จะอธิบายไว้ในไฟล์แนบแล้วก็ตาม ทั้งนี้เพื่ออำนวยความสะดวกแก่เพื่อนสมาชิกในการค้นหาข้อมูล
  4. ควรแนบตัวอย่างไฟล์มาที่ฟอรั่มนี้เพื่อเพิ่มความสะดวกในการตอบคำถาม (ขนาดไฟล์ไม่เกิน 500Kb ขนาดภาพไม่เกิน 800*600 Pixel) ไม่แนบเป็น Link มาจากแหล่งอื่น นอกจากนี้ไม่ควรแนบไฟลที่มีข้อมูลสำคัญอันก่อให้เกิดความเสียหายกับตนเองและผู้อื่น
  5. สำหรับคำถามเกี่ยวกับ VBA ให้ลองเขียนมาเองก่อนเสมอ ถามเฉพาะที่ติดปัญหา ระบุ Module, Procedure ที่ติดปัญหาให้ชัดเจน ควรโพสต์ Code ให้แสดงเป็น Code เพื่อสะดวกในการอ่านและทดสอบ (คลิกเพื่อดูตัวอย่าง)
  6. แจ้งผลการใช้งานเมื่อได้รับคำตอบว่าตรงกับความต้องการหรือไม่
User avatar
snasui
Site Admin
Site Admin
Posts: 21977
Joined: Sun Jan 24, 2010 12:33 pm
Location: Songkhla, Thailand
Contact:

Re: (Macro VBA)ต้องการดึงไฟล์มาทีละหลายๆไฟล์ นำมาแปลงไฟล์ครับ

#21

Postby snasui » Fri Sep 22, 2017 10:24 pm

:D ตัวอย่าง Code ครับ

Code: Select all

Sub Macro1()
' Macro1 Macro
    Dim strPath As Variant, i As Integer
    Dim fName As String, wb As Workbook, tb As Workbook
   
    Set tb = ThisWorkbook
    strPath = Application.GetOpenFilename("Text files(*.txt*),*.txt*", _
        Title:="Please select text files.", MultiSelect:=True)
    If TypeName(strPath) = "Boolean" Then Exit Sub
   
    For i = 1 To UBound(strPath)
        fName = VBA.Left(strPath(i), InStr(strPath(i), ".")) & "xlsx"
        Workbooks.OpenText Filename:=strPath(i), Origin:=874, _
            StartRow:=1, DataType:=xlDelimited, TextQualifier:=xlDoubleQuote, _
            ConsecutiveDelimiter:=True, Tab:=True, Semicolon:=False, Comma:=False, _
            Space:=True, Other:=False, FieldInfo:=Array(Array(1, 1), Array(2, 1), Array(3 _
            , 1), Array(4, 2), Array(5, 9), Array(6, 1), Array(7, 1), Array(8, 1), Array(9, 1), Array(10, _
            1), Array(11, 1), Array(12, 1), Array(13, 1), Array(14, 1), Array(15, 1), Array(16, 1), _
            Array(17, 1), Array(18, 1), Array(19, 1), Array(20, 1), Array(21, 3), Array(22, 4)), _
            TrailingMinusNumbers:=True
    Next i
    For Each wb In Workbooks
        If InStr(tb.Name & "incentive_A.txt" & "incentive_B.txt", wb.Name) = 0 Then
            With Workbooks("incentive_A.txt").Sheets(1)
                wb.Sheets(1).UsedRange.Offset(1, 0).Copy .Range("a" & .Rows.Count).End(xlUp).Offset(1, 0)
            End With
            With Workbooks("incentive_B.txt").Sheets(1)
                wb.Sheets(1).UsedRange.Offset(1, 0).Copy .Range("a" & .Rows.Count).End(xlUp).Offset(1, 0)
            End With
            wb.Close False
        End If
    Next wb
    With Workbooks("incentive_A.txt")
        .Sheets(1).Name = "incentive"
        .SaveAs Filename:=VBA.Left(.Name, InStrRev(.Name, ".") - 1), FileFormat:=xlOpenXMLWorkbook
        .Close False
    End With
    With Workbooks("incentive_B.txt")
        .Sheets(1).Name = "incentive"
        .SaveAs Filename:=VBA.Left(.Name, InStrRev(.Name, ".") - 1), FileFormat:=xlOpenXMLWorkbook
        .Close False
    End With
   
    MsgBox "Finish."
End Sub

User avatar
parakorn
Silver
Silver
Posts: 669
Joined: Thu Mar 14, 2013 9:41 am
Contact:

Re: (Macro VBA)ต้องการดึงไฟล์มาทีละหลายๆไฟล์ นำมาแปลงไฟล์ครับ

#22

Postby parakorn » Mon Sep 25, 2017 1:31 am

ขอบคุณมากๆครับอาจารย์ เดี๋ยวจะลองนำไปทดสอบดูครับผม :D
"," คือ ยูเนี่ยน ใช้เลือกช่วงใดบ้างให้คำนวณทั้งหมด(เลือกซ้ำคำนวณซ้ำ)
":" คือ เซต ใช้สร้างช่วงตารางข้อมูลระหว่าง2Cell
" "(เว้นวรรค) คือ อินเตอร์เซก ใช้สร้างเซตระหว่างจุดตัดเซตทั้งหมดที่ทับกัน

Array ต้องเป็น เซตเท่านั้น

User avatar
parakorn
Silver
Silver
Posts: 669
Joined: Thu Mar 14, 2013 9:41 am
Contact:

Re: (Macro VBA)ต้องการดึงไฟล์มาทีละหลายๆไฟล์ นำมาแปลงไฟล์ครับ

#23

Postby parakorn » Thu Oct 05, 2017 6:33 pm

ขอกลับมาปรับปรุงโค้ดเพื่อใช้แปลงข้อมูล โดย Run Code แล้วเลือกทุกไฟล์ทีเดียว
แต่ให้โค้ดทำงานทีละ 2 ไฟล์ครับ :D
โดยต้องการให้ทำงานดังนี้ครับ

จัดคู่ไฟล์ตามชื่อ
Incentive_A คู่กับ Incentive_B
โดยให้นำข้อมูล Incentive_B มาต่อไฟล์ Incentive_A แล้วแก้ไขชื่อชีท และชื่อไฟล์ เป็น Incentive
Incentive2_A คู่กับ Incentive2_B ทำงานเช่นเดียวกับคู่แรก แก้ชื่อเป็น Incentive2
IncentiveA_A คู่กับ IncentiveA_B ทำงานเช่นเดียวกับคู่ที่สอง แก้ชื่อเป็น IncentiveA


ไฟล์ต่างๆ ตามที่แนบครับ :D
You do not have the required permissions to view the files attached to this post.
"," คือ ยูเนี่ยน ใช้เลือกช่วงใดบ้างให้คำนวณทั้งหมด(เลือกซ้ำคำนวณซ้ำ)
":" คือ เซต ใช้สร้างช่วงตารางข้อมูลระหว่าง2Cell
" "(เว้นวรรค) คือ อินเตอร์เซก ใช้สร้างเซตระหว่างจุดตัดเซตทั้งหมดที่ทับกัน

Array ต้องเป็น เซตเท่านั้น

User avatar
snasui
Site Admin
Site Admin
Posts: 21977
Joined: Sun Jan 24, 2010 12:33 pm
Location: Songkhla, Thailand
Contact:

Re: (Macro VBA)ต้องการดึงไฟล์มาทีละหลายๆไฟล์ นำมาแปลงไฟล์ครับ

#24

Postby snasui » Thu Oct 05, 2017 8:58 pm

:D ช่วยปรับ Code สำหรับงานนี้มาด้วยครับ Code ที่ Mark ให้เป็น Comment จะต้องปรับมาเป็น Code ที่ใช้งานได้ หากปรับมาแล้วช่วยแจ้งด้วยว่าติดขัดบรรทัดใด จะได้ตอบต่อไปจากนั้นครับ

User avatar
parakorn
Silver
Silver
Posts: 669
Joined: Thu Mar 14, 2013 9:41 am
Contact:

Re: (Macro VBA)ต้องการดึงไฟล์มาทีละหลายๆไฟล์ นำมาแปลงไฟล์ครับ

#25

Postby parakorn » Fri Oct 06, 2017 9:40 am

ติดขัดที่ บรรทัด

Code: Select all

    For Each wb In Workbooks
        If InStr(tb.Name & "incentive_A.txt" & "incentive2_A.txt" & "incentiveA_A.txt", wb.Name) = 0 Then
       
       
            With Workbooks("incentive_A.txt").Sheets(1)
                wb.Sheets(1).UsedRange.Offset(1, 0).Copy .Range("a" & .Rows.Count).End(xlUp).Offset(1, 0)
            End With
            With Workbooks("incentive2_A.txt").Sheets(1)
                wb.Sheets(1).UsedRange.Offset(1, 0).Copy .Range("a" & .Rows.Count).End(xlUp).Offset(1, 0)
            End With
            With Workbooks("incentiveA_A.txt").Sheets(1)
                wb.Sheets(1).UsedRange.Offset(1, 0).Copy .Range("a" & .Rows.Count).End(xlUp).Offset(1, 0)
            End With
            wb.Close False
        End If
    Next wb


ซึ่งต้องการปรับโค้ดให้ Copy ข้อมูลไฟล์ที่ ชื่อ ด้านหน้า สัญลักษณ์ "_"(Under scroll) เหมือนกัน
Incentive2_A
Incentive2_B
มาต่อกันครับ


ตามไฟล์แนบครับ :D
You do not have the required permissions to view the files attached to this post.
"," คือ ยูเนี่ยน ใช้เลือกช่วงใดบ้างให้คำนวณทั้งหมด(เลือกซ้ำคำนวณซ้ำ)
":" คือ เซต ใช้สร้างช่วงตารางข้อมูลระหว่าง2Cell
" "(เว้นวรรค) คือ อินเตอร์เซก ใช้สร้างเซตระหว่างจุดตัดเซตทั้งหมดที่ทับกัน

Array ต้องเป็น เซตเท่านั้น

User avatar
snasui
Site Admin
Site Admin
Posts: 21977
Joined: Sun Jan 24, 2010 12:33 pm
Location: Songkhla, Thailand
Contact:

Re: (Macro VBA)ต้องการดึงไฟล์มาทีละหลายๆไฟล์ นำมาแปลงไฟล์ครับ

#26

Postby snasui » Fri Oct 06, 2017 9:16 pm

:D ตัวอย่างการปรับ Code ครับ

Code: Select all

Sub Macro1()
' Macro1 Macro
    Dim strPath As Variant, i As Integer
    Dim fName As String, wb As Workbook, tb As Workbook
    Dim d As Object, strFile As String, s As Variant
    Dim nb As Workbook
    Set d = CreateObject("Scripting.Dictionary")
   
    Set tb = ThisWorkbook
    strPath = Application.GetOpenFilename("Text files(*.txt*),*.txt*", _
        Title:="Please select text files.", MultiSelect:=True)
    If TypeName(strPath) = "Boolean" Then Exit Sub
   
    On Error Resume Next
    For i = 1 To UBound(strPath)
        fName = VBA.Left(strPath(i), InStr(strPath(i), ".")) & "xlsx"
        Workbooks.OpenText Filename:=strPath(i), Origin:=874, _
            StartRow:=1, DataType:=xlDelimited, TextQualifier:=xlDoubleQuote, _
            ConsecutiveDelimiter:=True, Tab:=True, Semicolon:=False, Comma:=False, _
            Space:=True, Other:=False, FieldInfo:=Array(Array(1, 1), Array(2, 1), Array(3 _
            , 1), Array(4, 2), Array(5, 9), Array(6, 1), Array(7, 1), Array(8, 1), Array(9, 1), Array(10, _
            1), Array(11, 1), Array(12, 1), Array(13, 1), Array(14, 1), Array(15, 1), Array(16, 1), _
            Array(17, 1), Array(18, 1), Array(19, 1), Array(20, 1), Array(21, 3), Array(22, 4)), _
            TrailingMinusNumbers:=True
            strFile = Mid(strPath(i), InStrRev(strPath(i), "\") + 1)
            strFile = VBA.Left(strFile, InStrRev(strFile, "_") - 1)
            If Not d.exists(strFile) Then
                d.Add Key:=strFile, Item:=strFile
            End If
    Next i
    On Error GoTo 0
    For Each s In d.keys
        Set nb = Workbooks.Add
        For Each wb In Workbooks
            If InStr(wb.Name, "_") Then
                If VBA.Left(wb.Name, InStrRev(wb.Name, "_") - 1) = s Then
                    If nb.Sheets(1).Range("a1") = "" Then
                        wb.Sheets(1).UsedRange.Copy nb.Sheets(1).Range("a1")
                    Else
                        wb.Sheets(1).UsedRange.Offset(1, 0).Copy nb.Sheets(1).Range("a" & _
                            nb.Sheets(1).Rows.Count).End(xlUp).Offset(1, 0)
                    End If
                    wb.Close False
                End If
            End If
        Next wb
        Application.CutCopyMode = False
        nb.Sheets(1).Name = s
        nb.SaveAs Filename:=s, FileFormat:=xlOpenXMLWorkbook
        nb.Close False
    Next s
    MsgBox "Finish."
End Sub

User avatar
parakorn
Silver
Silver
Posts: 669
Joined: Thu Mar 14, 2013 9:41 am
Contact:

Re: (Macro VBA)ต้องการดึงไฟล์มาทีละหลายๆไฟล์ นำมาแปลงไฟล์ครับ

#27

Postby parakorn » Tue Oct 10, 2017 7:59 pm

Success
ขอบพระคุณครับผม :cp: :cp:
"," คือ ยูเนี่ยน ใช้เลือกช่วงใดบ้างให้คำนวณทั้งหมด(เลือกซ้ำคำนวณซ้ำ)
":" คือ เซต ใช้สร้างช่วงตารางข้อมูลระหว่าง2Cell
" "(เว้นวรรค) คือ อินเตอร์เซก ใช้สร้างเซตระหว่างจุดตัดเซตทั้งหมดที่ทับกัน

Array ต้องเป็น เซตเท่านั้น


Return to “Excel”

Who is online

Users browsing this forum: No registered users and 31 guests