Page 1 of 1

การจัดข้อมูลตามฟอร์ม

Posted: Thu Dec 08, 2016 11:33 pm
by panumascha
สวัสดีค่ะ อยากสอบถามว่า ถ้าต้องการจัดข้อมูลตามฟอร์มที่กำหนดมาให้ ต้องทำอย่างไรหรอคะ

ข้อมูลที่มี
Day Place No Q
1/12/16 ss 001 2
1/12/16 ss 002 3
1/12/16 aa 005 4
2/12/16 ss 008 9

ข้อมูลตามฟอร์ม
Day Place No Q
1/12/16 ss 001,002 5
1/12/16 aa 005 4
2/12/16 ss 008 9

Re: การจัดข้อมูลตามฟอร์ม

Posted: Fri Dec 09, 2016 1:27 pm
by Serverchita
เพื่อง่ายต่อการตอบ แนบไฟล์มาด้วยครับ

Re: การจัดข้อมูลตามฟอร์ม

Posted: Fri Dec 09, 2016 9:20 pm
by panumascha
ขอโทษทีค่า ทำการแนบไฟล์แล้วนะคะ

Re: การจัดข้อมูลตามฟอร์ม

Posted: Fri Dec 09, 2016 10:02 pm
by snasui
:D คำว่า "ค่า" ที่ใช้แทน "ค่ะ" ผิดกฎการใช้บอร์ดข้อ 1 ด้านบนครับ

การที่ไม่อนุญาตให้ใช้ภาษาแชท เนื่องจากมีผู้ศึกษาฟอรัมนี้จากหลายประเทศ เมื่อแปลเป็นภาษาต่างประเทศแล้วจะสื่อความหมายผิดไปครับ

ตัวอย่างสูตรตามด้านล่างครับ
  1. เซลล์ E3 คีย์สูตร
    =IFERROR(LOOKUP(2,1/((A$2:A2=A3)*(B$2:B2=B3)),E$2:E2)&","&C3,C3&"")
    Enter > Copy ลงด้านล่าง
  2. เซลล์ G5 คีย์สูตร
    =IFERROR(INDEX(A$3:A$27,SMALL(IF(FREQUENCY(MATCH($A$3:$A$27&$B$3:$B$27,$A$3:$A$27&$B$3:$B$27,0),ROW($A$3:$A$27)-ROW($A$3)+1),ROW($A$3:$A$27)-ROW($A$3)+1),ROWS(G$5:G5))),"")
    Ctrl+Shift+Enter > Copy ไป H5 จากนั้น Copy ลงด้านล่าง
  3. เซลล์ I5 คีย์สูตร
    =IF(N(G5),LOOKUP(2,1/(($A$3:$A$27=G5)*($B$3:$B$27=H5)),$E$3:$E$27),"")
    Enter > Copy ลงด้านล่าง
  4. เซลล์ J5 คีย์สูตร
    =IF(N(G5),SUMIFS($D$3:$D$27,$A$3:$A$27,G5,$B$3:$B$27,H5),"")
    Enter > Copy ลงด้านล่าง

!
Note: Ctrl+Shift+Enter เป็นการสร้างสูตร Array โดยสามารถเลือกดำเนินการตามข้อ 1 หรือ 2 ด้านล่าง
  1. กรณีคีย์สูตรเอง เมื่อคีย์สูตรแล้ว แทนที่จะกด Enter ให้กดแป้น Ctrl และ Shift พร้อมกันค้างไว้แล้วกด Enter เพื่อสร้างเป็นสูตร Array
  2. กรณี Copy สูตรไปวางให้กดแป้น F2 เพื่อทำการ Edit Cell นั้นก่อน จากนั้นกดแป้น Ctrl และ Shift พร้อมกันค้างไว้แล้วตามด้วย Enter เพื่อสร้างเป็นสูตร Array
  3. หากกดแป้นถูกต้องสูตรนั้นจะมีเครื่องหมายปีกกาครอบ เช่น {=YourFormulas(...)} ปีกกานี้ไม่สามารถคีย์เข้าไปเอง จะต้องมาด้วยการกดแป้น Ctrl+Shift+Enter เท่านั้น ถ้ายังไม่เห็นปีกกาครอบสูตรแสดงว่ากดแป้นให้รับสูตรไม่ถูกต้อง
  4. การแก้ไขเปลี่ยนแปลงสูตร Array จะต้องกดแป้นให้รับสูตรด้วย Ctrl+Shift+Enter ทุกครั้ง