Page 2 of 2

Re: ดึงข้อมูล มาใส่ในฟอร์มที่กำหนด (Stock Card)

Posted: Tue Nov 29, 2016 7:05 pm
by snasui
:D ตัวอย่างสูตรตามด้านล่างครับ
  1. เซลล์ E4 คีย์สูตร
    =SUMIFS(Table1[จำนวน],Table1[วันที่ทำรายการ],A4,Table1[รหัสStock Card],$A$1,Table1[ID],E$2,Table1[หมายเหตุ],D4)
    Enter > Copy ลงด้านล่าง
  2. เซลล์ F4 คีย์สูตร
    =ABS(SUMIFS(Table1[จำนวน],Table1[วันที่ทำรายการ],A4,Table1[รหัสStock Card],$A$1,Table1[ID],F$2,Table1[หมายเหตุ],D4))
    Enter > Copy ลงด้านล่าง

Re: ดึงข้อมูล มาใส่ในฟอร์มที่กำหนด (Stock Card)

Posted: Tue Nov 29, 2016 9:13 pm
by Jackgarine
ขอบคุณคะอาจารย์
ใช้ได้แล้วคะ

Re: ดึงข้อมูล มาใส่ในฟอร์มที่กำหนด (Stock Card)

Posted: Wed Apr 03, 2019 9:15 pm
by nagatobimaru
จากข้อมูลของคุณ Jackgarine และผู้รู้รวมถึงอาจารย์ทำให้ผมทำไฟล์ออกมาใช้งานได้ แต่อยากต่อยอดและผมพยามแล้วแต่ยังคงติดเลยมาสอบถามเพิ่มครับ
จากไฟล์แนบ
ในแถบ Report เราสามารถเอาข้อมูล ตัดยอดแล้วคงเหลือมาโชว์ได้ไหมครับ สำหรับทุกรายการ
C3 = ยอดคงเหลือของรายการ t001
C4 = ยอดคงเหลือของรายการ t002

Re: ดึงข้อมูล มาใส่ในฟอร์มที่กำหนด (Stock Card)

Posted: Wed Apr 03, 2019 9:39 pm
by puriwutpokin
ที่ C3=SUMIFS(data!F$2:F$8,data!D$2:D$8,B3,data!A$2:A$8,"in")-SUMIFS(data!F$2:F$8,data!D$2:D$8,B3,data!A$2:A$8,"out") คัดลอกลงครับ

Re: ดึงข้อมูล มาใส่ในฟอร์มที่กำหนด (Stock Card)

Posted: Wed Apr 03, 2019 10:13 pm
by nagatobimaru
ขอบคุณ คุณpuriwutpokin มากครับผมจะลองประยุกต์ใช้กับไฟล์ที่ผมทำครับ ติดขัดตรงไหนจะมาสอบถามเพิ่มครับ

Re: ดึงข้อมูล มาใส่ในฟอร์มที่กำหนด (Stock Card)

Posted: Wed Apr 03, 2019 11:03 pm
by nagatobimaru
ขออนุญาต เพิ่มเติมอีกซัก1คำถามครับ

ในแถบ out เดิมเราใช้คำในการค้นหาคือ B3 และจะแสดงผลต่างๆที่ A8 เป็นต้นไป ถ้าเราใส่เงื่อนไขเพิ่ม ในช่อง B5 เรื่องเกี่ยวกับช่วงเวลาเป็นเดือน จะใช้อย่างไรครับเพื่อให้แสดงค่า

Re: ดึงข้อมูล มาใส่ในฟอร์มที่กำหนด (Stock Card)

Posted: Wed Apr 03, 2019 11:51 pm
by parakorn
nagatobimaru wrote: Wed Apr 03, 2019 11:03 pm ขออนุญาต เพิ่มเติมอีกซัก1คำถามครับ

ในแถบ out เดิมเราใช้คำในการค้นหาคือ B3 และจะแสดงผลต่างๆที่ A8 เป็นต้นไป ถ้าเราใส่เงื่อนไขเพิ่ม ในช่อง B5 เรื่องเกี่ยวกับช่วงเวลาเป็นเดือน จะใช้อย่างไรครับเพื่อให้แสดงค่า
ระบุมาด้วยครับว่าใส่เดือนแบบไหน เป็นตัวเลข ชื่อภาษาไทย หรือ อังกฤษ

Re: ดึงข้อมูล มาใส่ในฟอร์มที่กำหนด (Stock Card)

Posted: Thu Apr 04, 2019 5:33 am
by nagatobimaru
parakorn wrote: Wed Apr 03, 2019 11:51 pm
nagatobimaru wrote: Wed Apr 03, 2019 11:03 pm ขออนุญาต เพิ่มเติมอีกซัก1คำถามครับ

ในแถบ out เดิมเราใช้คำในการค้นหาคือ B3 และจะแสดงผลต่างๆที่ A8 เป็นต้นไป ถ้าเราใส่เงื่อนไขเพิ่ม ในช่อง B5 เรื่องเกี่ยวกับช่วงเวลาเป็นเดือน จะใช้อย่างไรครับเพื่อให้แสดงค่า
ระบุมาด้วยครับว่าใส่เดือนแบบไหน เป็นตัวเลข ชื่อภาษาไทย หรือ อังกฤษ
ภาษาอังกฤษ ครับ
format cells = 1-Apr-2019
in put data = 04/01/2019

Re: ดึงข้อมูล มาใส่ในฟอร์มที่กำหนด (Stock Card)

Posted: Thu Apr 04, 2019 9:20 am
by parakorn
A8 ปรับสูตรเป็น =IFERROR(INDEX(data!B$2:B$8,SMALL(IF(data!$D$2:$D$8=$B$3,IF(ISNUMBER(MATCH(data!$A$2:$A$8,$C$7:$D$7,0)),IF(TEXT(data!$B$2:$B$8,"mmm")=TEXT(out!$B$5,"mmm"),ROW(data!$A$2:$A$8)-ROW(data!$A$2)+1))),ROWS(A$8:A8))),"") Ctrl+Shift+Enter Copyไป Column B และลงด้านล่างครับ

Re: ดึงข้อมูล มาใส่ในฟอร์มที่กำหนด (Stock Card)

Posted: Thu Apr 04, 2019 1:32 pm
by nagatobimaru
parakorn wrote: Thu Apr 04, 2019 9:20 am A8 ปรับสูตรเป็น =IFERROR(INDEX(data!B$2:B$8,SMALL(IF(data!$D$2:$D$8=$B$3,IF(ISNUMBER(MATCH(data!$A$2:$A$8,$C$7:$D$7,0)),IF(TEXT(data!$B$2:$B$8,"mmm")=TEXT(out!$B$5,"mmm"),ROW(data!$A$2:$A$8)-ROW(data!$A$2)+1))),ROWS(A$8:A8))),"") Ctrl+Shift+Enter Copyไป Column B และลงด้านล่างครับ
ขอบคุณอีกครั้งครับ สามารถนำมาดัดแปลงและใช้ในไฟล์เรียบร้อยครับ ขอถามเพื่อต่อยอดอีกขั้นนึงคือ " หลังจากที่เราสามารถค้นหาเป็น"mmm"นั้น ถ้าเป็น ช่วงระหว่างเดือน (เฉพาะในปีนั้นๆ คือเช่นใส่ข้อมูลเฉพาะ 2019 ปีเดียว แต่อยากค้นหา เช่น เดือนมกราคม-เดือนมีนาคม ประมาณนี้สามารถทำได้ไหมครับ

Re: ดึงข้อมูล มาใส่ในฟอร์มที่กำหนด (Stock Card)

Posted: Thu Apr 04, 2019 2:07 pm
by parakorn
ลองเพิ่มเงื่อนไขในไฟล์แนบมาครับ ถ้าต้องการเพิ่มปี และ เดือน ต้องระบุให้ครบครับผมจะได้เขียนให้ครอบคลุมทั้งหมด
จากที่สร้างไป สนใจแค่เดือน ไม่ได้สนใจปีครับ

Re: ดึงข้อมูล มาใส่ในฟอร์มที่กำหนด (Stock Card)

Posted: Thu Apr 04, 2019 2:33 pm
by nagatobimaru
parakorn wrote: Thu Apr 04, 2019 2:07 pm ลองเพิ่มเงื่อนไขในไฟล์แนบมาครับ ถ้าต้องการเพิ่มปี และ เดือน ต้องระบุให้ครบครับผมจะได้เขียนให้ครอบคลุมทั้งหมด
จากที่สร้างไป สนใจแค่เดือน ไม่ได้สนใจปีครับ
ยังคงสนใจค้นหาเป็นช่วงระหว่างเดือนเช่นเดิมครับ เพราะตั้งใจจะทดสอบทำไฟล์แยกปีกันครับ ส่วนรายละเอียดผมใส่ไปในไฟล์แนบล่ะครับคือ
ในชีท out ช่องที่ค้นหาเพิ่มจากเดิม B3,B5 มี C5 เพิ่ม โดย B5-C5 เป็นช่วงเดือนที่กำหนดโดยจะสูงสุดคือ Jan-Dec ครับ
และให้เริ่มแสดงผลที่ A8 แบบเดิมครับ

Re: ดึงข้อมูล มาใส่ในฟอร์มที่กำหนด (Stock Card)

Posted: Thu Apr 04, 2019 3:23 pm
by parakorn
ปรับสูตรเป็น
=IFERROR(INDEX(data!B$2:B$8,SMALL(IF(data!$D$2:$D$8=$B$3,IF(ISNUMBER(MATCH(data!$A$2:$A$8,$C$7:$D$7,0)),IF(TEXT(data!$B$2:$B$8,"mm")>=TEXT(out!$B$5,"mm"),IF(TEXT(data!$B$2:$B$8,"mm")<=TEXT(out!$C$5,"mm"),ROW(data!$A$2:$A$8)-ROW(data!$A$2)+1)))),ROWS(A$8:A8))),"") Ctrl+Shift+Enter ครับ

Re: ดึงข้อมูล มาใส่ในฟอร์มที่กำหนด (Stock Card)

Posted: Thu Apr 04, 2019 4:55 pm
by nagatobimaru
parakorn wrote: Thu Apr 04, 2019 3:23 pm ปรับสูตรเป็น
=IFERROR(INDEX(data!B$2:B$8,SMALL(IF(data!$D$2:$D$8=$B$3,IF(ISNUMBER(MATCH(data!$A$2:$A$8,$C$7:$D$7,0)),IF(TEXT(data!$B$2:$B$8,"mm")>=TEXT(out!$B$5,"mm"),IF(TEXT(data!$B$2:$B$8,"mm")<=TEXT(out!$C$5,"mm"),ROW(data!$A$2:$A$8)-ROW(data!$A$2)+1)))),ROWS(A$8:A8))),"") Ctrl+Shift+Enter ครับ
ได้เลยครับแบบนี้ ขอบคุณสำหรับคำแนะนำครับ ผมขอตัวไปจัดการเพื่อให้เหมาะสมกับไฟล์ต้นฉบับของผม :thup: